/*
McL presented on its standard generators.
*/

G<x,y>:=Group<x,y|
x^2,
y^5,
(x,y)^5,
(x*y)^11,
(x*y^2)^12,
(x,y^2)^6,
(x*y*x*y^-2)^7,
(x,y^-2*x*y*x*y*x*y^2)^2, // R0 - redundant.
(x,y^-2*x*y^2*x*y^-1*x*y*(x*y^2)^2*x*y*x*y^-1),
(x,y*(x*y^2)^3)^2, // R1 - redundant.
(x,y^2*x*y*(x*y^2)^2)^2,
x*y*x*y^2*x*y^-2*x*y*x*y^-1*x*y^2*(x*y^-2*x*y)^2*(x*y^2*x*y^-2*x*y^2)^2,
(x,y^2*x*y^2*x*y^-1*x*y^2)^2,
(x,y^2*x*y)^4,
(x,y^2*x*y^2)^4 // R2 - redundant.
>;
a:=x;b:=y;

// Copies of U4(3).
M1:=sub<G|x,y*x*y^2*x*y^-1*x*y^-2>;
M1a:=sub<G|x,y^2*x*y^-1*x*y^-1*x*y>;
M1b:=sub<G|x,x^y,y*x*y^-2*x*y^2*x*y^-1>;
M1c:=sub<G|x,y*x*y^-1,(x*y^2*x*y^-2)^2>;
M1d:=sub<G|x,y*x*y^-1,(x,y*x*y^2)>;

// Conjugate copies of M22 [not necessarily conjugate to max2].
M2:=sub<G|x,y^-2*x*y^2*x*y>;
M2a:=sub<G|x,y*x*y^2*x*y^2*x*y>;

LL:=sub<G|x,y^-1*x*y*x*y*x*y>; // Copy of U4(2). Contains y*x*y^-1.
LL2:=sub<G|x,y^-2*x*y*x*y*x*y^2>; // Copy of U4(2). Contains x^y.
// LL and LL2 are conjugate.

H:=sub<G|x,y*(x,y)^2,(x,y^2)^3,(x,y^-2)^3>;
HH:=sub<G|x,y*(x,y)^2,(x,y^2)^3,(x,y^-2)^3,(x,y^-2*x*y*x*y*x*y^2)>;

/*
Demonstration of correctness.
Rels x^2=y^5=(xy)^11=1 imply that G is perfect and generated by
conjugates of x.
Rels x^2=[x,y]^5=[x,y^2]^6=1 imply that H centralises x.
If R0 is present then HH also centralises x.
Coset enumeration over H yields the expected index of 22275.
Thus group is McL or 3"McL (on preimages of standard generators).
Standard gens A, B of 3"McL satisfy o(A)=2, o(B)=5 and o(AB)=33,
so we do not have 3"McL.

This works without R0, R1 or R2.
Index(G,H:Hard:=true,Print:=2,Grain:=10^6,CosetLimit:=20*10^6);

Enumerations with R0, R1 and R2 added are easier, though still not easy.
[I haven't tried enumerating cosets of all the above subgroups yet.]
*/