/*
M24 presented on its standard generators.
*/

G<x,y>:=Group<x,y|
x^2,
y^3,
(x*y)^23,
(x,y)^12,
(x,y*x*y)^5,
(x*y*x*y*x*y^-1)^3*(x*y*x*y^-1*x*y^-1)^3,
// (x,y^-1*x*y*x*y)^5, // redundant, but quite useful.
(x*y*(x*y*x*y^-1)^3)^4
>;

a:=x;b:=y;

H:=sub<G|x,(x,y)^6,(x,y^-1)^6,y*x*y*(x,y*x*y)^2>;
// Visibly centralises x. Index is 31878.
HH:=sub<G|x,(x,y)^6,(x,y^-1)^6,y*x*y*(x,y*x*y)^2,(x*y*x*y*x*y^-1)^3>;
// Centralises x [slightly less visibly]. Index is 31878.
H1:=sub<G|x*y>;
// Cyclic of order 23.
H2:=sub<G|x,y*x*y*x*y^-1>;
// 4 o SL2(3), of order 48.


// Maximal subgroups of M24.
M1:=sub<G|y,x*y^-1*(x*y)^3*x>;
// M23, of index 24.
M2:=sub<G|x,y^(x*y*x*y)>;
// M22:2, of index 276.
M3:=sub<G|y,x*y*x*y^-1*x*y*x*y^-1*x*y^-1*x*y*x>;
// 2^4:A8, of index 759.
M4:=sub<G|x,(y*x)^6*y^-1>;
// M12:2, of index 1288.
M5:=sub<G|x,y^-1*(x*y)^2*x*y^-1*(x*y)^3*x*y^-1>;
// 2^6:3"S6, of index 1771.
M6:=sub<G|((x*y)^3*x*y^-1)^4,(y*x)^3*(y^-1*x)^2>;
// L3(4):S3, of index 2024.
M7:=sub<G|x,(y*x)^2*(y^-1*x)^2*(y*x)^2*y>;
// 2^6:(L3(2) x S3), of index 3795.
M8:=sub<G|x,((x*y*x*y^-1)^4)^(y^-1*x*y^-1*x*y*x*y^-1)>;
// L2(23), of index 40320.
M9:=sub<G|x,((x*y*x*y^-1)^4)^(y^-1*(x*y^-1)^4)>;
// L2(7), of index 1457280.



/*
Demonstrations of correctness:

Coset enumeration over <x*y> = 23.
This subgroup has index 10644480. The following works in Magma >= 2.8.

23*Index(G,H1:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=11*10^6);


Coset enumeration over <x,y*x*y*x*y^-1> = 4 o SL2(3), of order 48.
Let c=x, d=y^(x*y^-1)=y*x*y*x*y^-1.
Then x^2=y^3=(x*y*x*y*x*y^-1)^3*(x*y*x*y^-1*x*y^-1)^3=1 force
c^2=d^3=(c*d)^3*(c*d^-1)^3=1 [fairly visibly, using x=x^-1] and these
relations force <c,d> = 4 o SL2(3).
This subgroup has index 5100480. The following works in Magma >= 2.8.

48*Index(G,H2:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=6*10^6);


Coset enumeration over a subgroup centralising an involution.
The relations x^2=y^3=(x*y)^23=1 force G to be perfect and generated by
conjugates of x.
The relation [x,y]^12=1 forces [x,y]^6 and [x,y^-1]^6 to centralise x.
The relation [x,yxy]^5=1 forces yxy[x,yxy]^2 to centralise x.
The relation (xyxy^-1xy^-1)^3(xyxyxy^-1)^3=1 (Trivially equivalent to
(xyxyxy^-1)^3(xyxy^-1xy^-1)^3=1) demonstrates that (xyxyxy^-1)^3
centralises x.
Thus both H and HH centralise x. In fact H = HH has index 31878 in G, the
same as what we expect in M24, which has trivial Schur multiplier.
Thus G = M24. The following works in Magma >= 2.8.

Index(G,H:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=4*10^6);
Index(G,HH:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10^6);
*/