/*
HS presented on its standard generators.
*/

G<x,y>:=Group<x,y|
x^2,
y^5,
(x*y)^11,
(x*y^2)^10,
(x,y)^5,
(x,y*x*y)^3,
(x,y^2)^6,
x*y*x*y*x*y^2*x*y^-1*x*y^-2*x*y^-1*x*y^2*x*y*x*y*(x*y^-2)^4,
x*y*(x*y^2*(x*y^-2)^2)^2*x*y^2*x*y*x*y^2*(x*y^-1*x*y^2)^2,
x*y*x*y*(x*y^2)^2*x*y*(x*y^-1)^2*x*y*(x*y^2)^2*x*y*x*y*x*y^-2*x*y^-1*x*y^-2,
(x*y*x*y*x*y^2*x*y^-1*x*y^-2*x*y*x*y*x*y^-1)^2, // R1.
(x*y*x*y*x*y^2)^2*x*y*x*y*x*y^-1*x*y*x*y*(x*y^2)^3*x*y*x*y*x*y^-1, // R2.
x*y*(x*y*x*y^2)^3*x*y*x*y*x*y^2*x*y^-1*x*y*x*y^-2*x*y*x*y^-1*x*y^2 // R3.
>;
// R1, R2 and R3 are redundant, but appear to be useful.

// Both of these subgroups have index 100 (and are equal).
M1:=sub<G|x,x^y,y*x*y^-1,x^(y^2*x*y^2)>;
M1a:=sub<G|x,x^y,y*x*y^-1>;

// This subgroup centralises x and has index 5775.
H:=sub<G|x,y*(x,y)^2,y*x*y*(x,y*x*y),(x,y^2)^3,(x,y^-2)^3>;

// This subgroup is cyclic of order 11.
K:=sub<G|x*y>;

/*
Demonstrations of correctness.
Rels x^2=y^5=(x*y)^11=1 demonstrate that G is perfect and generated by
conjugates of x.
H visibly centralises x. Coset enumeration over H establishes the index
5775, the same as in the image HS.
The double cover 2"HS is excluded since x*y^2 is in class 10B and lifts
to elements of order 20 in 2"HS [and we have the relation (x*y^2)^10 = 1].

K = <x*y> is cyclic of order 11 (or trivial), so enumerating the 4032000
cosets of this subgroup is also a way of establishing the order of G.
This enumeration is very hard without the redundant relations.


The following should work:

// Without the redundant relations.
Index(G,H:Print:=2,Hard:=true,Grain:=5*10^5,CosetLimit:=15*10^6);
Index(G,M1:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10000);
Index(G,M1a:Print:=2,Hard:=true,Grain:=5*10^5,CosetLimit:=2*10^6);
Index(G,K:Print:=2,Hard:=true,Grain:=5*10^5,CosetLimit:=53*10^6);

// With the redundant relations R1+R2+R3.
Index(G,H:Print:=2,Hard:=true,Grain:=5*10^5,CosetLimit:=10^6);
Index(G,M1:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10000);
Index(G,M1a:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10000);
Index(G,K:Print:=2,Hard:=true,Grain:=5*10^5,CosetLimit:=6*10^6);
*/