/*
3"Fi22:2 presented on its standard generators.
*/

G<x,y>:=Group<x,y|
x^2,
y^18,
(x,y^6)^2,
(x,y^7)^2,
(x*y^9)^4, // Redundant.
(x,y)^3,
(x,y^2)^3,
(x,y^3)^3,
(x,y^4)^3,
(x,y^5)^3,
(x,y^8)^3,
(x,y*x*y*x*y^-2*x*y),
(x,y^2*x*y^2*x*y^-4*x*y^2),
((x*y^3)^4*x*y^-4)^2,
(x*y^4*x*y^5*x*y^5)^5
>;

DG:=sub<G|x,y^2,y*x*y>;

H1:=sub<G|x,(x,y^6),(x,y^-6),(x,y^7),(x,y^-7),(x*y^9)^2,y*(x,y),y^2*(x,y^2),
y^3*(x,y^3),y^4*(x,y^4),y^5*(x,y^5),y^8*(x,y^8)>;
H2:=sub<G|x,(x,y^6),(x,y^-6),(x,y^7),(x,y^-7),y*(x,y),y^2*(x,y^2),
y^3*(x,y^3),y^4*(x,y^4),y^5*(x,y^5),y^8*(x,y^8)>;
// H1 = H2 = C_G(x), of index 3510.

/*
Demonstration of correctness:

Relations imply that G' = <x,y^2,y*x*y> has index 2 in G and is perfect.
[Some of these calculations are done within magma.]
Also G' is generated by conjugates of x, indeed by the x^(y^i).

Relations imply that H1 and H2 centralise x (though H1 can only be guaranteed
to do this if the relation (x*y^9)^4=1 is present).
Coset enumeration over H1/H2 gives the expected index of 3510.

Schur multiplier of Fi22 is 6 (the conjugates of x generate a group that
only maps onto Fi22), so the possible groups we have presented are
Fi22:2, 2"Fi22:2 (two such), 3"Fi22:2 or 6"Fi22:2 (two such).

But y^9 maps onto Fi22:2-class 2D, and our relations force y^9 to have order 2,
so that the 2"Fi22:2 and 6"Fi22:2 possibilities must the ATLAS-versions.

If G has 2"Fi22:2 (ATLAS-version) as an image then (x,y) or (x*c,y) are
standard generators for it, where c is the central involution. In either
case, we get that [x,y] has order 6 (using the 352-diml GF(3)-repn), whereas
our relations force [x,y] to have order 3, so 2"Fi22:2 and 6"Fi22:2 cannot
be images of G.

If we have presented 3"Fi22:2, it must be on standard generators since our
relations ensure that o(x) = 2 (or 1). Explicit computations in the 54-diml
GF(2)-rep of 3"Fi22:2 show that 3"Fi22:2 is an image of our finitely
presented group.

Therefore G is 3"Fi22:2.


The central 3 [in G'] is given by (x*y*x*y^-3)^8.


Required enumerations.

With (x*y^9)^4.
Index(G,H1:Print:=2,Hard:=true,CosetLimit:=10^6,Grain:=10^5);

Without (x*y^9)^4.
Index(G,H2:Print:=2,Hard:=true,CosetLimit:=12*10^6,Grain:=10^6);
*/