/*
4b"M20 as 4 x 4 matrices over Z[i].
Absolutely irreducible representation.
Schur Index 1.

SEED:
Nonzero v negated by x and x^(yxy) where <x,x^(yxy)> = S4.
v has 4 x 40 = 160 images under G; <v> has 40 images under G.
BASIS:
All in v^G.

Possible matrix entries for any element of the group:
The 9 elements of {0,1,-1,i,-i,1+i,1-i,-1+i,-1-i} only.
The possible norms are in {0,1,2} only.

Average number of nonzero entries for any element of the group:
11 + 1/5  (11.2; 70% exactly).

Entry    Av/Mat  %Av/Mat
   0      4.8     30
   1      1.6     10
  -1      1.6     10
   i      1.6     10
  -i      1.6     10
 1+i      1.2      7.5
 1-i      1.2      7.5
-1+i      1.2      7.5
-1-i      1.2      7.5
Norm 0    4.8     30
Norm 1    6.4     40
Norm 2    4.8     30
nonzero  11.2     70
*/

F<i>:=QuadraticField(-1);

G<x,y>:=MatrixGroup<4,F|[
-1,0,0,0,
-1,i,-i+1,0,
-1,0,-i-1,1,
-1,0,-i,0]
,\[
0,1,0,0,
0,0,1,0,
1,0,0,0,
0,0,0,1]
>;

// Complex conjugates of x and y.
xc:=GL(4,F)![Conjugate(u):u in Eltseq(x)];
yc:=GL(4,F)![Conjugate(u):u in Eltseq(y)];

// Forms: B1 (Hermitian).
// B1 (Hermitian form): Determinant 1.
B1:=MatrixAlgebra(F,4)![
2,i,-i,1,
-i,2,i,1,
i,-i,2,1,
1,1,1,2];

// Centralising algebra: Scalars only.
C1:=MatrixAlgebra(F,4)!Eltseq(y^3);