/*
U5(2):2 presented on its standard generators.
*/

G<x,y>:=Group<x,y|
x^2,
y^4,
(x*y)^11,
(x*y^2)^6,
(x*y*x*y^2)^4,
(x,y)^9, // Can use (x*y*x*y*x*y^-1)^6 instead.
(x*y^-1*(x*y*x*y*x*y^-1)^2*x*y^2)^2,
(y^2,x*y*x*y*x)^3
>;

H:=sub<G|y,(x*y^2)^3,x*y*x*y*x*(y^2,x*y*x*y*x)>;
// H = C_G(y^2) [order 9216, index 2970].
K1:=sub<G|x*y>;
// K1 = C11.

M1:=sub<G|y^2,x*y>;
M2:=sub<G|x,y*x*y^-1*x*y^-1*x*y*x*y*x*y^2>;
M3:=sub<G|x,y*x*y^2*x*y^2>;
M4:=sub<G|y,x*y*x*y*x*y^-1*x>;
M5:=sub<G|x,y*x*y*x*y^-1*x*y^-1*x*y*x*y>;
M6:=sub<G|x,y^2,(y*x*y)^2,(x*y*x*y*x*y^2)^2*x*y*x*y^-1*x*y^2*x*y*x*y>;
M7:=sub<G|y^2,y^(x*y*x*y*x)>;
// Maximal subgroups of G: U5(2), 2^{1+6}.3^{1+2}.2S4, (3 x U4(2)):2,
// 2^{4+4}:(3xA5):2, 3^4:(S5x2), S3 x 3^{1+2}:2S4, L2(11):2.


/*
Demonstrations of correctness:
1st one:
Relations x^2 = y^4 = (x*y^2)^6 = 1 = [y^2,x*y*x*y*x]^3 imply that
H centralises y^2.
Relations x^2 = y^4 = (x*y)^11 = [x,y]^9 = 1 show that G/G' = 2 (at most)
and that G' is perfect, and that G' is generated by the conjugates of y^2.
Coset enumeration over H gives the expected index of 2970.
Since U5(2) has trivial Schur multiplier, we conclude that G = U5(2):2.

2nd one:
Coset enumeration over K1 = C11 (index is 2488320).


The following enumerations should work.
Index(G,H:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,K1:Print:=2,Hard:=true,Grain:=10^6,CosetLimit:=3*10^6);
Index(G,M1:Print:=2,Hard:=true,CosetLimit:=100);
Index(G,M2:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M3:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M4:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M5:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10^6);
Index(G,M6:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M7:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10^6);
*/