/*
A presentation for U5(2) in terms of its standard generators.
SGens for U5(2) are x in 2A, y in 5A s.t. xy has order 11.
*/

G<x,y>:=Group<x,y|
x^2,
y^5,
(x*y)^11,
(x,y)^3,
(x,y^2)^3,
(x,y*x*y)^3,
(x,y*x*y^2)^3
>;

H:=sub<G|x,y*x*y^-1*x*y,y^2*x*y^-2*x*y^2>;
K1:=sub<G|x*y>;
K2:=sub<G|x,x^y,y*x*y^-1>;
K3:=sub<G|x,x^y,y*x*y^-1,x^(y^2)>;
// H = C_G(x).
// K1 = 11.
// K2 = <a,b,c|a^2=b^2=c^2=(ab)^3=(bc)^3=(ac)^3=(abac)^3=1> = 3^{1+2}:2.
// K3 = 2^{1+6}:3^{1+2}:2, normal in 2^{1+6}:3^{1+2}:2A4.

M1:=sub<G|x,y*x*y^-1*x*y,y^2*x*y^-2*x*y^2>; // Same as H.
M2:=sub<G|x,y*x*y*x*y^-2*x*y>;
M2a:=sub<G|x*y^2,(x*y^-2)^5>; // Conjugate to M2.
M3:=sub<G|y,x*y^2*x*y^-2*x*y*x*y*x*y*x*y^-1*x>;
M4:=sub<G|x,y^(x*y)>;
M5:=sub<G|x,x^y,y*x*y^-1,(x*y^2)^2*(x*y)^3*(x*y^2)^2,y^-2*x*y*(x*y^-2)^2*(x*y)^3*x*y^2*x*y^-2>;
M6:=sub<G|y,x*y*(x*y^2)^2*x*y*(x*y^-1)^2*x*y^2*x>;
// Maximal subgroups.

H2:=sub<G|x,y^(x*y^2)>;
// U4(2).

/*
Demonstrations of correctness:

Proof 1:
Coset enumeration over K1 = <x*y> = C11 (index 1244160).

Proof 2:
From relations 1, 4, 5 and 6, we see that a = x, b = x^y and c = y*x*y^-1
satisfy the presentation:
<a,b,c|a^2=b^2=c^2=(ab)^3=(bc)^3=(ac)^3=(abac)^3=1>,
showing that K2 = <a,b,c> has order (at most) 54.
To see that (abac)^3=1, express Relation 6 in the form
(x*y^-1*x*y*x*y*x*y^-1)^3 = 1.
The enumerate the cosets of K2 (index 253440).

Proof 2b?:
Work out what K3 is from the relations [1, 4, 5, 6 and 7]. (I haven't tried
this, so I don't know if this can made to work.) Coset enumeration over K3
is very easy, and the index is 1980.

Proof 3:
Relations x^2 = y^5 = (x*y)^11 = 1 show that G is perfect and generated
by conjugates of x. From the relations x^2 = [x,y]^3 = [x,y^2]^3 = 1 we
see that H centralises x.
Coset enumeration shows that H has index 165 in G, the same as we expect
in the image U5(2).
Since the Schur multiplier of U5(2) is trivial, we have G = U5(2).


The following enumerations should work.

Index(G,H:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,K3:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,K2:Print:=2,Hard:=true,Grain:=10^6,CosetLimit:=2*10^6);
Index(G,K1:Print:=2,Hard:=true,Grain:=10^6,CosetLimit:=11*10^6);
// indexes 165, 1980, 253440, 1244160.

Index(G,M1:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M2:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M2a:Print:=2,Hard:=true,Grain:=10^6,CosetLimit:=2*10^6);
Index(G,M3:Print:=2,Hard:=true,Grain:=10^6,CosetLimit:=2*10^6);
Index(G,M4:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M5:Print:=2,Hard:=true,CosetLimit:=10000);
Index(G,M6:Print:=2,Hard:=true,Grain:=10^5,CosetLimit:=10^6);
Index(G,H2:Print:=2,Hard:=true,CosetLimit:=100000);
*/